Mengatasi IP Dinamis speedy dengan DDNS

Ketika kita berlangganan ISP, sebagian dari kita menggunakan mikrotik. Akan tetapi untuk saat ini jika anda menggunakan speedy denga kuota dibawah 3 Mb, jangan harap kita bisa dapat ip publik static. Tutorial ini khusus bagi anda yang menggunakan mikrotik, bisa dipakai, baik versi Mikrotik pada PC maupun routerboard (pake winbox).
Padahal terkadang ketika kita tidak dirumah, misal di sekolah, atau sedang keluar kota, kita butuh me-remote  mikrotik kita. Padahal jika kita tidak memiliki ip static, kita akan kebingungan untuk mengakses mikrotik kita yang dirumah. Karena itu perlu kita untuk mengakalinya.
Jika anda mempunyai kartu kredit, anda bis pakae DynDns, karena harus menggunakan kartu kredit untuk pembayaran, tetapi kalau anda senang dengan DDNS yang Gratis anda bisa dapat di cangeip.net
Untuk tutor kali ini kita akan menggunakan ChangeIP  yang menyediakan free ddns. Sebelum menggunakan Dyndns tapi sekarang udah ga Gratis lagi dan tentunya mikrotik anda sudah set PPPOE dial up dimikrotik.
Berikut Step by stepnya khusus ROS V.5xx untuk versi dibawahnya bisa lihat dari sumbernya disini
Langkah :
1. Daftar di www.changeip.net
2. Buka Winbox System-Scripts



Sesuai kan yang didalam kotak ID,PASS,HOST yang baru terdaftar.
berikut scriptnya :
# Written by Sam Norris, ChangeIP.com
# Copyright ChangeIP.com 2009
# For support send mail to Support@ChangeIP.com
#
# 2009-06-22 RouterOS 3.25 Tested
# 2009-10-05 RouterOS 4.01rc1 Tested
#
# OVERVIEW:         %
#  This script will update a ChangeIP.com dynamic dns hostname
#  with an ip address located directly on an interface.
#                   %
# NOTES:            %
#  IF THIS SCRIPT DOES NOT PRODUCE ANY OUTPUT PLEASE COPY AND PASTE IT
#  AGAIN.  THERE PROBABLY IS A LINE BREAK IN THE WRONG PLACE! Once you
#  have created this script and tested that it works by running it
#  manually you can schedule it to run every few minutes.
#                   %
# CONFIGURATION FIELD DEFINITIONS:
#  ddnsuser:  Enter your ChangeIP.com user id.
#  ddnspass:  Enter your ChangeIP.com password.
#  ddnshost:  Enter the hostname (www.example.com) to update.
#  ddnsinterface:  Enter an interface name to watch - case sensative.
#                   %
#                   %
#                   %
#                   %
#               %   %   %
#                %  %  %
#                 % % %
#                   %
# ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
# EDIT YOUR DETAILS / CONFIGURATION HERE
# ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
:global ddnsuser "YourChangeIPUserID"
:global ddnspass "PASSWORD"
:global ddnshost "MyRouterHostname.example.org"
:global ddnsinterface "ether1"
# ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
# END OF USER DEFINED CONFIGURATION
# ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:global ddnssystem ("mt-" . [/system package get [/system package find name=system] version] )
:global ddnsip [ /ip address get [/ip address find interface=$ddnsinterface] address ]
:global ddnslastip

:if ([:len [/interface find name=$ddnsinterface]] = 0 ) do={ :log info "DDNS: No interface named $ddnsinterface, please check configuration." }

:if ([ :typeof $ddnslastip ] = "nothing" ) do={ :global ddnslastip 0.0.0.0/0 }

:if ([ :typeof $ddnsip ] = "nothing" ) do={

:log info ("DDNS: No ip address present on " . $ddnsinterface . ", please check.")

} else={

  :if ($ddnsip != $ddnslastip) do={

    :log info "DDNS: Sending UPDATE!"
    :log info [ :put [/tool dns-update name=$ddnshost address=[:pick $ddnsip 0 [:find $ddnsip "/"] ] key-name=$ddnsuser key=$ddnspass ] ]
    :global ddnslastip $ddnsip

  } else={

    :log info "DDNS: No changes necessary."

  }

}



Beri Nama script ChangeIP
3. Tambahkan schedule seperti dibawah ini . pastekan di New Terminal

/system scheduler add comment="" disabled=no interval=5m name=DDNS on-event=\ ChangeIP policy=read,write,policy,test,password start-time=\ startup



Seep segitu aja aja Gan,
Sumber : http://wiki.mikrotik.com/wiki/Dynamic_DNS_Update_Script_for_ChangeIP.com

Source : http://jatibarang.blogspot.com/2012/10/remote-mikrotik-speedy-dengan-ip.html